I am giving VoodooPad a run as my “everything bucket” and wrote an AppleScript to import my 500+ Yojimbo notes into my VoodooPad notebook. If you are looking to do something similar, this script may be of help or at least a good place to start.

Here’s how it works:

• The script targets the frontmost VoodooPad document.

• It creates a VoodooPad page for every imported Yojimbo note. I wrote the script assuming the VoodooPad New Page Format preference was set to Markdown, so I never tested RTF as a destination format. However, I believe RTF to RTF should work fine.

• It also creates an index page in VoodooPad with VoodooPad links to all imported notes. This index is formatted using Markdown syntax and will be named “Imported Yojimbo Notes” by default. The name can be customized via the import_name variable.

• By default the script will import all notes from the Yojimbo library into VoodooPad using the Yojimbo note name as the VoodooPad page name. However, there are a few lines in the script that allow you to tweak this behavior:

  1. You can modify the main repeat loop to either pull all notes in the Yojimbo library or only certain notes based on a given criteria. The example in the script is a name search, but it could be any scriptable criteria.

  2. I used Bruce Phillips’ search and replace AppleScript function to provide an option to remove or replace text from certain titles. Note: this is commented out in the example script.

  3. I used Qwerty Denzel’s AppleScript modify case functions to provide an option to change the case of the note titles going into VoodooPad. Note: this is also commented out in the example script.

• Once the import is done, it does not delete the notes in Yojimbo, but instead tags them with “@imported to VoodooPad”.

Enjoy.

(* An AppleScript to Import Yojimbo Notes into VoodooPad
        Written by: Ken Clark
        Published on: December 31, 2012
        About this script: http://www.nineboxes.net/2012/12/an-applescript-to-import-yojimbo-notes-into-voodoopad/
        Contributing Code:
        * Search and Replace AppleScript code by Bruce Phillips: http://foolsworkshop.com/applescript/2008/05/an-applescript-replace-text-method/
        * AppleScript text case functions by Qwerty Denzel: http://macscripter.net/viewtopic.php?id=13297 
    *)

property alphaList : "abcdefghijklmnopqrstuvwxyz"'s items & reverse of "ABCDEFGHIJKLMNOPQRSTUVWXYZ"'s items
set import_name to "Imported Yojimbo Notes" -- the name of the VoodooPad index page for the imported notes. 
set import_index to "# " & import_name & "

    "
tell application "Yojimbo"
    -- Note: The script includes two examples for looping through Yojimbo. The first (commented) repeat loop only selects notes that start with a particular phrase. The second (uncommented) repeat loop gets all notes in the Yojimbo library. You can modify the syntax of these repeat loops to select notes on other criteria based on your needs.

    -- Example one: get every note in the Yojimbo library that starts with a given term or phrase
    -- repeat with y_item in (every note item in library whose name starts with "enter text here")

    -- Example two: select every note in the Yojimbo library (default)
    repeat with y_item in every note item in library
        set item_name to the name of y_item
        set item_contents to the content of y_item
        -- Note: this block is commented out by default as you would only use it if you want to manipulate the name of the Yojimbo item before it goes into VoodooPad. 
        (*tell me
                -- Option one: this line will replace certain phrases in your titles before the import. This example removes "Applescript:" from titles of notes.
                set item_name to replaceText("AppleScript: ", "", item_name)
                -- Option two: this line will title case all note names before the import.
                set item_name to changeCase of item_name to "title"  
            end tell*)
        set page_content to "# " & item_name & "

    " & item_contents
        tell application "VoodooPad"
            tell document 1 to create new page with name item_name with content page_content
        end tell
        set import_index to import_index & "* " & item_name & "
    "
        -- This adds a "@imported to Voodoopad" tag to every Yojimbo note that was imported into VoodooPad. Comment this out if you don't want that. 
        add tags "@imported to VoodooPad" to y_item
    end repeat
end tell

-- Create import index
tell application "VoodooPad"
    tell document 1 to create new page with name import_name with content import_index
end tell

-- ** Subroutines **

-- ReplaceText function by Bruce Phillips
on replaceText(find, replace, subject)
    set prevTIDs to text item delimiters of AppleScript
    set text item delimiters of AppleScript to find
    set subject to text items of subject

    set text item delimiters of AppleScript to replace
    set subject to "" & subject
    set text item delimiters of AppleScript to prevTIDs

    return subject
end replaceText

-- Modify Case with AppleScript by Qwerty Denzel
on textItems from t
    try
        t's text items
    on error number -2706
        tell (count t's text items) div 2 to my (textItems from (t's text 1 thru text item it)) & my (textItems from (t's text from text item (it + 1) to -1))
    end try
end textItems

to changeCase of t to c
    if (count t) is 0 then return t
    considering case
        if c is not in {"upper", "lower", "title", "sentence"} then
            error "The word \"" & c & "\" is not a valid option. Please use \"upper\", \"lower\", \"title\" or \"sentence\"."
        else if c is "upper" then
            set n to 1
        else
            set n to -1
        end if
        set d to text item delimiters
        repeat with n from n to n * 26 by n
            set text item delimiters to my alphaList's item n
            set t to textItems from t
            set text item delimiters to my alphaList's item -n
            tell t to set t to beginning & ({""} & rest)
        end repeat
        if c is in {"title", "sentence"} then
            if c is "title" then
                set s to space
            else
                set s to ". "
            end if
            set t to (t's item 1 & s & t)'s text 2 thru -1
            repeat with i in {s, tab, return, ASCII character 10}
                set text item delimiters to i
                if (count t's text items) > 1 then repeat with n from 1 to 26
                    set text item delimiters to i & my alphaList's item n
                    if (count t's text items) > 1 then
                        set t to textItems from t
                        set text item delimiters to i & my alphaList's item -n
                        tell t to set t to beginning & ({""} & rest)
                    end if
                end repeat
            end repeat
            set t to t's text ((count s) + 1) thru -1
        end if
        set text item delimiters to d
    end considering
    t
end changeCase